qp_plugins_scemama/devel/cc/form_r1.irp.f

subroutine form_r1(hvv,hoo,hvo,t1,t2,tau,r1)

! Form tau in CCSD

  implicit none

! Input variables

  double precision,intent(in)   :: hvv(spin_vir_num,spin_vir_num)
  double precision,intent(in)   :: hoo(spin_occ_num,spin_occ_num)
  double precision,intent(in)   :: hvo(spin_vir_num,spin_occ_num)

  double precision,intent(in)   :: t1(spin_occ_num,spin_vir_num)
  double precision,intent(in)   :: t2(spin_occ_num,spin_occ_num,spin_vir_num,spin_vir_num)
  double precision,intent(in)   :: tau(spin_occ_num,spin_occ_num,spin_vir_num,spin_vir_num)

! Local variables

  integer                       :: i,j,k,l
  integer                       :: a,b,c,d

! Output variables

  double precision,intent(out)  :: r1(spin_occ_num,spin_vir_num)

  r1(:,:) = 0d0

  do a=1,spin_vir_num
      do i=1,spin_occ_num

        do b=1,spin_vir_num
          r1(i,a) = r1(i,a) + hvv(b,a)*t1(i,b)
        end do

        do j=1,spin_occ_num
          r1(i,a) = r1(i,a) - hoo(i,j)*t1(j,a)
        end do

        do j=1,spin_occ_num
          do b=1,spin_vir_num
            r1(i,a) = r1(i,a) + hvo(b,j)*(t2(i,j,a,b) + t1(i,b)*t1(j,a))
          end do
        end do

        do b=1,spin_vir_num
          do j=1,spin_occ_num
            r1(i,a) = r1(i,a) + OVVO(i,b,a,j)*t1(j,b)
          end do
        end do

        do c=1,spin_vir_num
          do b=1,spin_vir_num
            do j=1,spin_occ_num
              r1(i,a) = r1(i,a) - OVVV(j,a,b,c)*tau(i,j,b,c)
            end do
          end do
        end do

        do b=1,spin_vir_num
          do k=1,spin_occ_num
            do j=1,spin_occ_num
              r1(i,a) = r1(i,a) - OOOV(j,k,i,b)*tau(j,k,a,b)
            end do
          end do
        end do

    end do
  end do

end subroutine form_r1