quack/src/QuAcK/Bethe_Salpeter_A_matrix_dynamic.f90

subroutine Bethe_Salpeter_A_matrix_dynamic(eta,nBas,nC,nO,nV,nR,nS,lambda,OmRPA,OmBSE,rho,A_lr)

! Compute the dynamic part of the Bethe-Salpeter equation matrices

  implicit none
  include 'parameters.h'

! Input variables

  integer,intent(in)            :: nBas,nC,nO,nV,nR,nS
  double precision,intent(in)   :: eta
  double precision,intent(in)   :: lambda
  double precision,intent(in)   :: OmRPA(nS)
  double precision,intent(in)   :: OmBSE
  double precision,intent(in)   :: rho(nBas,nBas,nS)
  
! Local variables

  double precision              :: chi
  double precision              :: eps
  integer                       :: i,j,a,b,ia,jb,kc

! Output variables

  double precision,intent(out)  :: A_lr(nS,nS)

  A_lr(:,:) = 0d0

  ia = 0
  do i=nC+1,nO
    do a=nO+1,nBas-nR
      ia = ia + 1
      jb = 0
      do j=nC+1,nO
        do b=nO+1,nBas-nR
          jb = jb + 1
 
          chi = 0d0
          do kc=1,nS

            eps = OmRPA(kc)**2 + eta**2
            chi = chi + rho(i,j,kc)*rho(a,b,kc)*OmRPA(kc)/eps

          enddo

          A_lr(ia,jb) = A_lr(ia,jb) - 4d0*lambda*chi

          chi = 0d0
          do kc=1,nS

            eps = (OmBSE - OmRPA(kc))**2 + eta**2
            chi = chi + rho(i,j,kc)*rho(a,b,kc)*(OmBSE - OmRPA(kc))/eps

            eps = (OmBSE + OmRPA(kc))**2 + eta**2
            chi = chi - rho(i,j,kc)*rho(a,b,kc)*(OmBSE + OmRPA(kc))/eps

          enddo

          A_lr(ia,jb) = A_lr(ia,jb) - 2d0*lambda*chi

        enddo
      enddo
    enddo
  enddo

end subroutine Bethe_Salpeter_A_matrix_dynamic