open Util
open Lacaml.D
open Bigarray
open Powers
open Coordinate

let cutoff = Constants.cutoff 
let cutoff2 = cutoff *. cutoff

exception NullQuartet
exception Found

let at_least_one_valid arr =
  try
    Array.iter (fun x -> if (abs_float x > cutoff) then raise Found) arr ; false
  with Found -> true


(** Horizontal and Vertical Recurrence Relations (HVRR) *)
let hvrr_two_e_vector (angMom_a, angMom_b, angMom_c, angMom_d)
    zero_m_array
    (expo_b, expo_d)
    (expo_inv_p, expo_inv_q)
    (center_ab, center_cd, center_pq)
    (center_pa, center_qc)
    map_1d map_2d np nq
  =

  let get_xyz angMom = 
    match angMom with
    | { y=0 ; z=0 ; _ } -> X
    | {       z=0 ; _ } -> Y
    | _                 -> Z
  in

  (** Vertical recurrence relations *)
  let rec vrr0_v m angMom_a = 
    match angMom_a.tot with
    | 0 -> zero_m_array.(m)
    | _ ->
      let key = Zkey.of_powers_three angMom_a
      in

      try Zmap.find map_1d.(m) key with
      | Not_found -> 
        let result = 
          let xyz = get_xyz angMom_a in
          let am  = Powers.decr xyz angMom_a in
          let cab = Coordinate.get xyz center_ab in
          let p0  = vrr0_v (m+1) am in

          let result = Array.make_matrix np nq 0. in
          begin
            if abs_float cab >= cutoff then
                let v0 = vrr0_v m am in
                Array.iteri (fun l result_l ->
                    let f0 = -. expo_b.(l) *. expo_inv_p.(l) *. cab
                    and v0_l = v0.(l) 
                    in
                    Array.iteri (fun k v0_lk ->
                        result_l.(k) <- v0_lk *. f0) v0_l ) result
          end;
          let amxyz = Powers.get  xyz am in
          if amxyz < 1 then
              Array.iteri (fun l result_l ->
                  let expo_inv_p_l = expo_inv_p.(l) 
                  and center_pq_xyz_l = (center_pq xyz).(l)
                  and result_l = result.(l)
                  and p0_l = p0.(l)
                  in
                  Array.iteri (fun k p0_lk ->
                      result_l.(k) <- result_l.(k)
                                      +. expo_inv_p_l *. center_pq_xyz_l.(k) *. p0_lk
                    ) p0_l ) result
          else
              begin
                let amm = Powers.decr xyz am in
                let v1 = vrr0_v m amm in
                let v2 = vrr0_v (m+1) amm in
                let amxyz = float_of_int amxyz  in
                Array.iteri (fun l result_l ->
                    let f = amxyz *. expo_inv_p.(l) *. 0.5 
                    and expo_inv_p_l = expo_inv_p.(l)
                    and center_pq_xyz_l = (center_pq xyz).(l)
                    and v1_l = v1.(l)
                    and v2_l = v2.(l)
                    and result_l = result.(l)
                    in
                    Array.iteri (fun k p0_lk ->
                        result_l.(k) <- result_l.(k) +.
                                        expo_inv_p_l *. center_pq_xyz_l.(k) *. p0_lk +.
                                        f *. (v1_l.(k) +. v2_l.(k) *. expo_inv_p_l) 
                      ) p0.(l)
                  ) result
              end;
          result 
        in
        Zmap.add map_1d.(m) key result;
        result

  and vrr_v m angMom_a angMom_c =

    match (angMom_a.tot, angMom_c.tot) with
    | (i,0) -> Some (vrr0_v m angMom_a)
    | (_,_) ->

      let key =  Zkey.of_powers_six angMom_a angMom_c in

      try Zmap.find map_2d.(m) key with
      | Not_found -> 
        let result = 
          begin
            let xyz = get_xyz angMom_c in
            let cm = Powers.decr xyz angMom_c in
            let axyz  = Powers.get xyz angMom_a in

            let do_compute = ref false in
            let v1 =
              let f = -. (Coordinate.get xyz center_cd) in

              let f1 =
                Array.init nq (fun k ->
                    let x = expo_d.(k) *. expo_inv_q.(k) *. f in
                    if ( (not !do_compute) && (abs_float x > cutoff) ) then
                      do_compute := true;
                    x)
              in
              if (!do_compute) then
                match vrr_v m angMom_a cm with
                | None -> None
                | Some v1 -> 
                  begin
                    Some (Array.init np (fun l ->
                      let v1_l = v1.(l) in
                      Array.mapi (fun k f1k -> v1_l.(k) *. f1k) f1
                    ) )
                  end
              else None
            in

            let v2 =
              let f2 =
                Array.init np (fun l ->
                    let cpq_l = (center_pq xyz).(l) in
                    Array.init nq (fun k ->
                        let x = expo_inv_q.(k) *. cpq_l.(k) in
                        if (!do_compute) then x
                        else (if abs_float x > cutoff then do_compute := true ; x)
                      ) )
              in
              if (!do_compute) then
                match vrr_v (m+1) angMom_a cm with
                | None -> None
                | Some v2 -> 
                  begin
                    for l=0 to np-1 do
                      let f2_l = f2.(l)
                      and v2_l = v2.(l)
                      in
                      for k=0 to nq-1 do
                        f2_l.(k) <- -. v2_l.(k) *. f2_l.(k)
                      done
                    done;
                    Some f2
                  end
              else None
            in

            let p1 = 
              match v1, v2 with
              | None, None -> None
              | None, Some v2 -> Some v2
              | Some v1, None -> Some v1
              | Some v1, Some v2 ->
                begin
                  for l=0 to np-1 do
                    let v1_l = v1.(l)
                    and v2_l = v2.(l)
                    in
                    for k=0 to nq-1 do
                      v2_l.(k) <- v2_l.(k) +. v1_l.(k)
                    done
                  done;
                  Some v2
                end
            in

            let cxyz = Powers.get  xyz angMom_c in
            let p2 = 
              if cxyz < 2 then p1 else
                let cmm = Powers.decr xyz cm in
                let fcm = (float_of_int (cxyz-1)) *. 0.5 in
                let f1 =
                  Array.init nq (fun k ->
                      let x = fcm *. expo_inv_q.(k) in
                      if (!do_compute) then x
                      else (if abs_float x > cutoff then do_compute := true ; x)
                    )
                in
                let v1 = 
                  if (!do_compute) then
                    match vrr_v m angMom_a cmm with
                    | None -> None
                    | Some v1 -> 
                      begin
                        let result = Array.make_matrix np nq 0. in
                        for l=0 to np-1 do
                          let v1_l = v1.(l)
                          and result_l = result.(l)
                          in
                          for k=0 to nq-1 do
                            result_l.(k) <- v1_l.(k) *. f1.(k)
                          done;
                        done;
                        Some result
                      end
                  else None
                in

                let v3 = 
                  let f2 = 
                    Array.init nq (fun k -> 
                        let x = expo_inv_q.(k) *. f1.(k) in
                        if (!do_compute) then x
                        else (if abs_float x > cutoff then do_compute := true ; x)
                      )
                  in
                  if (!do_compute) then
                    match vrr_v (m+1) angMom_a cmm with
                    | None -> None
                    | Some v3 -> 
                      begin
                        let result = Array.make_matrix np nq 0. in
                        for l=0 to np-1 do
                          let v3_l = v3.(l)
                          and result_l = result.(l)
                          in
                          for k=0 to nq-1 do
                            result_l.(k) <- v3_l.(k) *. f2.(k)
                          done
                        done;
                        Some result
                      end
                  else None
                in
                match p1, v1, v3 with
                | None, None, None    -> None
                | Some p1, None, None -> Some p1
                | None, Some v1, None -> Some v1
                | None, None, Some v3 -> Some v3
                | Some p1, Some v1, Some v3 ->
                  begin
                    for l=0 to np-1 do
                      let v3_l = v3.(l)
                      and v1_l = v1.(l)
                      and p1_l = p1.(l)
                      in
                      for k=0 to nq-1 do
                        v3_l.(k) <- p1_l.(k) +. v1_l.(k) +. v3_l.(k)
                      done
                    done;
                    Some v3
                  end
                | Some p1, Some v1, None ->
                  begin
                    for l=0 to np-1 do
                      let v1_l = v1.(l)
                      and p1_l = p1.(l)
                      in
                      for k=0 to nq-1 do
                        p1_l.(k) <- v1_l.(k) +. p1_l.(k)
                      done
                    done;
                    Some p1
                  end
                | Some p1, None, Some v3 ->
                  begin
                    for l=0 to np-1 do
                      let v3_l = v3.(l)
                      and p1_l = p1.(l)
                      in
                      for k=0 to nq-1 do
                        p1_l.(k) <- p1_l.(k) +. v3_l.(k)
                      done
                    done;
                    Some p1
                  end
                | None   , Some v1, Some v3 ->
                  begin
                    for l=0 to np-1 do
                      let v3_l = v3.(l)
                      and v1_l = v1.(l)
                      in
                      for k=0 to nq-1 do
                        v3_l.(k) <- v1_l.(k) +. v3_l.(k)
                      done
                    done;
                    Some v3
                  end
            in
            if (axyz < 1) || (cxyz < 1) then p2 else
              let am = Powers.decr xyz angMom_a in
              let v = 
                vrr_v (m+1) am cm
              in
              match (p2, v) with
              | None, None   -> None
              | Some p2, None -> Some p2
              | _, Some v ->
                begin
                  let p2 =
                    match p2 with
                    | None -> Array.make_matrix np nq 0.
                    | Some p2 -> p2
                  in
                  for l=0 to np-1 do
                    let fa = (float_of_int axyz) *. expo_inv_p.(l) *. 0.5 in
                    let p2_l = p2.(l)
                    and v_l = v.(l)
                    in
                    for k=0 to nq-1 do
                      p2_l.(k) <- p2_l.(k) -. fa *. expo_inv_q.(k) *. v_l.(k)
                    done
                  done;
                  Some p2
                end
          end
        in Zmap.add map_2d.(m) key result;
        result

(*
  and trr_v angMom_a angMom_c =

    match (angMom_a.tot, angMom_c.tot) with
    | (i,0) -> Some (vrr0_v 0 angMom_a)
    | (_,_) ->

      let key =  Zkey.of_powers_six angMom_a angMom_c in

      try Zmap.find map_2d.(0) key with
      | Not_found -> 
          let xyz   = get_xyz angMom_c in
          let axyz  = Powers.get  xyz angMom_a in
          let cm    = Powers.decr xyz angMom_c in
          let cmxyz = Powers.get  xyz cm       in
          let expo_inv_q_over_p =
            Array.mapi (fun l expo_inv_p_l ->
              let expo_p_l = 1./.expo_inv_p_l in
              Array.mapi (fun k expo_inv_q_k ->
                expo_inv_q_k *. expo_p_l) expo_inv_q ) expo_inv_p
          in
          let result = None in

          let result =
            if cmxyz < 1 then result else
              begin
                let f = 0.5 *. (float_of_int cmxyz)  in
                let cmm = Powers.decr xyz cm in
                match result, trr_v angMom_a cmm with
                | None, None -> None
                | None, Some v3 ->
                    Some (Array.init np (fun l ->
                      let v3_l = v3.(l) in
                      Array.mapi  (fun k v3_lk ->
                        expo_inv_q.(k) *. f *. v3_lk) v3_l
                    ) )
                | Some result, None -> Some result
                | Some result, Some v3 ->
                    (Array.iteri (fun l v3_l ->
                      let result_l = result.(l) in
                      Array.iteri (fun k v3_lk ->
                      result_l.(k) <- result_l.(k) +.
                        expo_inv_q.(k) *. f *. v3_lk) v3_l
                    ) v3 ; Some result)
              end
          in
          let result =
            begin
              match result, trr_v angMom_a cm with
              | Some result, None -> Some result
              | Some result, Some v1 ->
                    (Array.iteri (fun l v1_l ->
                      let cpa = (center_pa xyz).(l)
                      and result_l = result.(l)
                      and expo_inv_q_over_p_l = expo_inv_q_over_p.(l)
                      in
                      Array.iteri (fun k v1_lk -> 
                        let cqc = (center_qc xyz).(k) in
                        result_l.(k) <- result_l.(k) +.
                        (cqc +. expo_inv_q_over_p_l.(k) *. cpa) *. v1_lk 
                      ) v1_l
                    ) v1 ; Some result)
              | None, None -> None
              | None, Some v1 ->
                    Some (Array.init np (fun l ->
                      let v1_l = v1.(l) 
                      and cpa = (center_pa xyz).(l)
                      and expo_inv_q_over_p_l = expo_inv_q_over_p.(l)
                      in
                      Array.mapi (fun k v1_lk ->
                        let cqc = (center_qc xyz).(k) in
                        (cqc +. expo_inv_q_over_p_l.(k) *. cpa) *. v1_lk 
                      ) v1_l
                    ) )
            end
          in
          let result =
            if cmxyz < 0 then result else
              begin
                let ap = Powers.incr xyz angMom_a in
                match result, trr_v ap cm with
                | Some result, None -> Some result
                | Some result, Some v4 ->
                    (Array.iteri (fun l v4_l ->
                      let result_l = result.(l) in
                      Array.iteri (fun k v4_lk ->
                      let expo_inv_q_over_p_l = expo_inv_q_over_p.(l) in
                      result_l.(k) <- result_l.(k) 
                        -. expo_inv_q_over_p_l.(k) *. v4_lk) v4_l
                    ) v4 ; Some result)
                | None, None -> None
                | None, Some v4 ->
                    Some (Array.init np (fun l ->
                      let v4_l = v4.(l) in
                      let expo_inv_q_over_p_l = expo_inv_q_over_p.(l) in
                      Array.mapi  (fun k v4_lk ->
                        -. expo_inv_q_over_p_l.(k) *. v4_lk) v4_l
                    ) )
              end
          in
          let result =
            if axyz < 1 then result else
              begin
                let f = 0.5 *. (float_of_int axyz)  in
                let am = Powers.decr xyz angMom_a in
                match result, trr_v am cm with
                | Some result, None -> Some result
                | Some result, Some v2 ->
                    (Array.iteri (fun l v2_l ->
                      let result_l = result.(l) in
                      Array.iteri (fun k v2_lk ->
                      result_l.(k) <- result_l.(k) +.
                        expo_inv_q.(k) *. f *. v2_lk) v2_l
                    ) v2; Some result)
                | None, None -> None
                | None, Some v2 ->
                    Some (Array.init np (fun l ->
                      let v2_l = v2.(l) in
                      Array.mapi  (fun k v2_lk ->
                        expo_inv_q.(k) *. f *. v2_lk) v2_l
                    ) )
              end
          in
          Zmap.add map_2d.(0) key result;
          result
          *)
  in

  let sum matrix =
    Array.fold_left (fun accu c -> accu +. Array.fold_left (+.) 0. c) 0. matrix
  in

  let vrr_v a b = 
    let v = 
      (*
      if Array.length zero_m_array < 10 then
      *)
      vrr_v 0 a b
      (*
      else trr_v a b
      *)
    in
    match v with 
      | None -> 0.
      | Some matrix -> sum matrix
  in


  (** Horizontal recurrence relations *)
  let rec hrr0_v angMom_a angMom_b angMom_c =

    match angMom_b.tot with
    | 0 ->
      begin
        match (angMom_a.tot, angMom_c.tot) with
        | (0,0) -> sum zero_m_array.(0)
        | (_,_) -> vrr_v angMom_a angMom_c
      end
    | 1 ->
      let xyz  = get_xyz angMom_b in
      let ap = Powers.incr xyz angMom_a in
      let f  = Coordinate.get xyz center_ab in
      let v1 = vrr_v ap angMom_c in
      if (abs_float f < cutoff) then v1 else
          let v2 = vrr_v angMom_a angMom_c in
          v1 +. v2 *. f
    | _ ->
      let xyz  = get_xyz angMom_b in
      let bxyz = Powers.get xyz angMom_b in
      if (bxyz < 0) then 0. else
          let ap = Powers.incr xyz angMom_a in
          let bm = Powers.decr xyz angMom_b in
          let h1 = hrr0_v ap bm angMom_c in
          let f = Coordinate.get xyz center_ab in
          if abs_float f < cutoff then h1 else
              let h2 = hrr0_v angMom_a bm angMom_c in
              h1 +. h2 *. f

  and hrr_v angMom_a angMom_b angMom_c angMom_d =

    match (angMom_b.tot, angMom_d.tot) with
    | (_,0) -> if angMom_b.tot = 0 then
          vrr_v angMom_a angMom_c
      else
        hrr0_v angMom_a angMom_b angMom_c 
    | (_,_) ->
      let xyz  = get_xyz angMom_d in
      let cp = Powers.incr xyz angMom_c in
      let dm = Powers.decr xyz angMom_d in 
      let h1 = 
        hrr_v angMom_a angMom_b cp dm 
      in
      let f = Coordinate.get xyz center_cd in
      if abs_float f < cutoff then
        h1
      else
        let h2 =
          hrr_v angMom_a angMom_b angMom_c dm 
        in h1 +. f *. h2
  in
  hrr_v angMom_a angMom_b angMom_c angMom_d







let contracted_class_shell_pairs ~zero_m ?schwartz_p ?schwartz_q shell_p shell_q : float Zmap.t =

  let shell_a = shell_p.ContractedShellPair.shell_a
  and shell_b = shell_p.ContractedShellPair.shell_b
  and shell_c = shell_q.ContractedShellPair.shell_a
  and shell_d = shell_q.ContractedShellPair.shell_b
  and sp = shell_p.ContractedShellPair.shell_pairs
  and sq = shell_q.ContractedShellPair.shell_pairs
  in
  let maxm = 
    shell_p.ContractedShellPair.totAngMomInt +
    shell_q.ContractedShellPair.totAngMomInt 
  in

  (* Pre-computation of integral class indices *)
  let class_indices = 
    Angular_momentum.zkey_array
      (Angular_momentum.Quartet
         Contracted_shell.(totAngMom shell_a, totAngMom shell_b,
                           totAngMom shell_c, totAngMom shell_d))
  in

  let contracted_class = 
    Array.make (Array.length class_indices) 0.;
  in

  let monocentric =
      shell_p.ContractedShellPair.monocentric &&
      shell_q.ContractedShellPair.monocentric &&
      Contracted_shell.center shell_p.ContractedShellPair.shell_a =
      Contracted_shell.center shell_q.ContractedShellPair.shell_a
  in

  (** Screening on the product of coefficients *)
  let coef_max_p =
    Array.fold_left (fun accu x ->
      if (abs_float x) > accu then (abs_float x) else accu)
      0. shell_p.ContractedShellPair.coef
  and coef_max_q =
    Array.fold_left (fun accu x ->
      if (abs_float x) > accu then (abs_float x) else accu)
      0. shell_q.ContractedShellPair.coef
  in

  let rec build_list cutoff vec accu = function
  | -1 -> Array.of_list accu
  | k  -> build_list cutoff vec ( 
            if (abs_float vec.(k) > cutoff) then (k::accu)
            else accu ) (k-1)
  in
  let p_list =
    let vec = shell_p.ContractedShellPair.coef  in
    build_list (cutoff /. coef_max_q) vec [] (Array.length vec - 1)
  and q_list =
    let vec = shell_q.ContractedShellPair.coef  in
    build_list (cutoff /. coef_max_p) vec [] (Array.length vec - 1)
  in

  let np, nq = 
    Array.length p_list,
    Array.length q_list
  in
  let filter_p vec = Array.init np (fun k -> vec.(p_list.(k)))
  and filter_q vec = Array.init nq (fun k -> vec.(q_list.(k)))
  in
  let sp = filter_p sp
  and sq = filter_q sq
  in


  (* Compute all integrals in the shell for each pair of significant shell pairs *)

  begin
    match Contracted_shell.(totAngMom shell_a, totAngMom shell_b,
                            totAngMom shell_c, totAngMom shell_d) with
    | Angular_momentum.(S,S,S,S) ->
      contracted_class.(0) <-
        begin
          try
            let expo_inv_p = 
              Vec.init np (fun ab -> sp.(ab-1).ShellPair.expo_inv) 
            and expo_inv_q = 
              Vec.init nq (fun cd -> sq.(cd-1).ShellPair.expo_inv) 
            in

            let coef =
              let result = Mat.make0 nq np in
              Lacaml.D.ger
                (Vec.of_array @@ filter_q shell_q.ContractedShellPair.coef)
                (Vec.of_array @@ filter_p shell_p.ContractedShellPair.coef)
                result;
              result
            in
            let zm_array = Mat.init_cols np nq (fun i j ->
                try
                  if (abs_float coef.{j,i} ) < 1.e-3*.cutoff then
                    raise NullQuartet;

                  let expo_pq_inv =
                    expo_inv_p.{i} +. expo_inv_q.{j}
                  in

                  let center_pq =
                    sp.(i-1).ShellPair.center |- sq.(j-1).ShellPair.center
                  in
                  let norm_pq_sq =
                    Coordinate.dot center_pq center_pq
                  in

                  let zero_m_array = 
                    zero_m ~maxm:0 ~expo_pq_inv ~norm_pq_sq
                  in
                  zero_m_array.(0)
                with NullQuartet -> 0.
              ) in
            Mat.gemm_trace zm_array coef
          with (Invalid_argument _) -> 0.
        end
    | _ -> 

      let coef =
        let cp = filter_p shell_p.ContractedShellPair.coef
        and cq = filter_q shell_q.ContractedShellPair.coef
        in
        Array.init np (fun l -> Array.init nq (fun k -> cq.(k) *. cp.(l)) )
      in

      let expo_inv_p = 
        Array.map (fun shell_ab -> shell_ab.ShellPair.expo_inv) sp
      and expo_inv_q = 
        Array.map (fun shell_cd -> shell_cd.ShellPair.expo_inv) sq 
      in

      let expo_b =
        Array.map (fun shell_ab -> Contracted_shell.expo shell_b shell_ab.ShellPair.j) sp
      and expo_d =
        Array.map (fun shell_cd -> Contracted_shell.expo shell_d shell_cd.ShellPair.j) sq
      in
      let norm_coef_scale_p = shell_p.ContractedShellPair.norm_coef_scale in

      let center_pq =
        let result = 
        Array.init 3 (fun xyz ->
          Array.init np (fun ab ->
            let shell_ab = sp.(ab) in
            Array.init nq (fun cd ->
                let shell_cd = sq.(cd)
                in
                let cpq = 
                  shell_ab.ShellPair.center |- shell_cd.ShellPair.center
                in
                match xyz with
                | 0 -> Coordinate.get X cpq;
                | 1 -> Coordinate.get Y cpq;
                | _ -> Coordinate.get Z cpq;
              ) 
            )
          )
          in function 
          | X -> result.(0)
          | Y -> result.(1)
          | Z -> result.(2)
      in
      let center_pa =
        let result = 
        Array.init 3 (fun xyz ->
          Array.init np (fun ab ->
            let shell_ab = sp.(ab) in
                let cpa = 
                  shell_ab.ShellPair.center |- Contracted_shell.center shell_a
                in
                match xyz with
                | 0 -> Coordinate.get X cpa;
                | 1 -> Coordinate.get Y cpa;
                | _ -> Coordinate.get Z cpa;
              ) 
          )
          in function 
          | X -> result.(0)
          | Y -> result.(1)
          | Z -> result.(2)
      in
      let center_qc =
        let result = 
        Array.init 3 (fun xyz ->
          Array.init nq (fun cd ->
            let shell_cd = sq.(cd) in
                let cqc = 
                  shell_cd.ShellPair.center |- Contracted_shell.center shell_c
                in
                match xyz with
                | 0 -> Coordinate.get X cqc;
                | 1 -> Coordinate.get Y cqc;
                | _ -> Coordinate.get Z cqc;
              ) 
          )
          in function 
          | X -> result.(0)
          | Y -> result.(1)
          | Z -> result.(2)
      in
      let zero_m_array =
        let result = 
          Array.init (maxm+1) (fun _ ->
            Array.init np (fun _ -> Array.make nq 0. ) )
        in
        let empty = Array.make (maxm+1) 0. in
        Array.iteri (fun ab shell_ab ->
            let zero_m_array_tmp =
              Array.mapi (fun cd shell_cd ->
                  if (abs_float coef.(ab).(cd) < cutoff) then
                    empty
                  else
                    let expo_pq_inv =
                      expo_inv_p.(ab) +. expo_inv_q.(cd)
                    in
                    let norm_pq_sq =
                      let x = (center_pq X).(ab).(cd)
                      and y = (center_pq Y).(ab).(cd)
                      and z = (center_pq Z).(ab).(cd)
                      in
                      x *. x +. y *. y +. z *. z
                    in

                    zero_m ~maxm ~expo_pq_inv ~norm_pq_sq
              ) sq
            in
            (* Transpose result *)
              for m=0 to maxm do
                for cd=0 to nq-1 do
                  result.(m).(ab).(cd) <- zero_m_array_tmp.(cd).(m) *. coef.(ab).(cd)
                done
              done
          ) sp;
          result
        in

        let norm = 
          let norm_coef_scale_q =
            shell_q.ContractedShellPair.norm_coef_scale
          in
          Array.to_list norm_coef_scale_p
          |> List.map (fun v1 ->
              Array.map (fun v2 -> v1 *. v2) norm_coef_scale_q)
          |> Array.concat
        in

        let map_1d = Array.init (maxm+1) (fun _ -> Zmap.create (4*maxm))
        and map_2d = Array.init (maxm+1) (fun _ -> Zmap.create (Array.length class_indices))
        in
          (* Compute the integral class from the primitive shell quartet *)
            Array.iteri (fun i key ->
                let (angMom_a,angMom_b,angMom_c,angMom_d) =
                  match Zkey.to_powers ~kind:Zkey.Kind_12 key with
                  | Zkey.Twelve x -> x
                  | _             -> assert false
                in
                try
                  if monocentric then
                    begin
                    if ( ((1 land angMom_a.x + angMom_b.x + angMom_c.x + angMom_d.x) =1) ||
                         ((1 land angMom_a.y + angMom_b.y + angMom_c.y + angMom_d.y) =1) ||
                         ((1 land angMom_a.z + angMom_b.z + angMom_c.z + angMom_d.z) =1)
                        ) then
                        raise NullQuartet
                    end;

                   (* Schwartz screening *)
                  if (np+nq> 24) then
                  (
                    let schwartz_p = 
                      let key = Zkey.of_powers_twelve
                       angMom_a  angMom_b  angMom_a  angMom_b 
                      in
                      match schwartz_p with
                      | None -> 1.
                      | Some schwartz_p -> Zmap.find schwartz_p key
                    in
                    if schwartz_p < cutoff then raise NullQuartet;
                    let schwartz_q = 
                      let key = Zkey.of_powers_twelve
                       angMom_c  angMom_d  angMom_c  angMom_d 
                      in
                      match schwartz_q with
                      | None -> 1.
                      | Some schwartz_q -> Zmap.find schwartz_q key
                    in
                    if schwartz_p *. schwartz_q < cutoff2 then raise NullQuartet;
                    );
 
                  let integral = 
                    hvrr_two_e_vector (angMom_a, angMom_b, angMom_c, angMom_d)
                       zero_m_array
                      (expo_b, expo_d)
                      (expo_inv_p, expo_inv_q)
                      (shell_p.ContractedShellPair.center_ab,
                       shell_q.ContractedShellPair.center_ab, center_pq)
                      (center_pa, center_qc)
                      map_1d map_2d np nq
                  in
                  contracted_class.(i) <- contracted_class.(i) +. integral *. norm.(i)
                with NullQuartet -> ()
              ) class_indices

  end;

  let result = 
    Zmap.create (Array.length contracted_class)
  in
  Array.iteri (fun i key -> Zmap.add result key contracted_class.(i)) class_indices;
  result



(** Computes all the two-electron integrals of the contracted shell quartet *)
let contracted_class ~zero_m shell_a shell_b shell_c shell_d : float Zmap.t =

  let shell_p = ContractedShellPair.create ~cutoff shell_a shell_b
  and shell_q = ContractedShellPair.create ~cutoff shell_c shell_d
  in
  contracted_class_shell_pairs ~zero_m shell_p shell_q